s c h e m a t i c s : c o o k b o o k

;;;
;;; Clock
;;;

;; This program demonstrates how to use a timer
;; together with a GUI.

(require (lib "date.ss"))

;;; GUI

; The GUI consists of a frame with the title "Clock".
; The contents of the frame is a message, where the
; time is written every second.

(define frame (make-object frame% "Clock"))
(define time-message (make-object message% "The time is written here" frame))
(send frame show #t)


;;; DATE AND STRING FUNCTIONS

; pad2 makes sure the string length is 2 by padding with
; an extra 0, if neccessary
(define (pad2 s)
  (if (< (string-length s) 2)
      (string-append "0" s)
      s))

; time->string : -> string
;   returns a string with the current time
(define (time->string)
  (let* ([date     (seconds->date (current-seconds))]
         [seconds  (number->string (date-second date))]
         [minutes  (number->string (date-minute date))]
         [hours    (number->string (date-hour date))] )         
    (string-append (pad2 hours)
                   ":"
                   (pad2 minutes)
                   ":"
                   (pad2 seconds))))

;;; TIMER

; The timer calls the callback function every
; 1000 milliseconds (that is every second)

(instantiate timer% () 
  (notify-callback (lambda ()
                     (send time-message set-label (time->string))))
  (interval 1000)
  (just-once? #f) )